EXSLT - date:leap-year - EXSLT Function Implementation

User Page

How To

Downloads

Modules

Dates and Times

date:add()

date:add-duration()

date:date()

date:date-time()

date:day-abbreviation()

date:day-in-month()

date:day-in-week()

date:day-in-year()

date:day-name()

date:day-of-week-in-month()

date:difference()

date:duration()

date:format-date()

date:hour-in-day()

date:leap-year()

EXSLT Function

XSLT Template

Javascript

Msxsl

date:minute-in-hour()

date:month-abbreviation()

date:month-in-year()

date:month-name()

date:parse-date()

date:second-in-minute()

date:seconds()

date:sum()

date:time()

date:week-in-month()

date:week-in-year()

date:year()

date:date-format

Dynamic

Common

Functions

Math

Random

Regular Expressions

Sets

Strings

Submissions

Mailing List

Contact

Supported Version: 1
XML Definition: date.leap-year.xml
Source: date.leap-year.function.xsl

Source

<xsl:param name="date:date-time"
           select="'2000-01-01T00:00:00Z'" />
<func:function name="date:leap-year">
   <xsl:param name="date-time">
      <xsl:choose>
         <xsl:when test="function-available('date:date-time')">
            <xsl:value-of select="date:date-time()" />
         </xsl:when>
         <xsl:otherwise>
            <xsl:value-of select="$date:date-time" />
         </xsl:otherwise>
      </xsl:choose>
   </xsl:param>
   <xsl:variable name="neg"
                 select="starts-with($date-time, '-')" />
   <xsl:variable name="dt-no-neg">
      <xsl:choose>
         <xsl:when test="$neg or starts-with($date-time, '+')">
            <xsl:value-of select="substring($date-time, 2)" />
         </xsl:when>
         <xsl:otherwise>
            <xsl:value-of select="$date-time" />
         </xsl:otherwise>
      </xsl:choose>
   </xsl:variable>
   <xsl:variable name="dt-no-neg-length"
                 select="string-length($dt-no-neg)" />
   <xsl:variable name="timezone">
      <xsl:choose>
         <xsl:when test="substring($dt-no-neg, $dt-no-neg-length) = 'Z'">Z</xsl:when>
         <xsl:otherwise>
            <xsl:variable name="tz"
                          select="substring($dt-no-neg, $dt-no-neg-length - 5)" />
            <xsl:if test="(substring($tz, 1, 1) = '-' or                             substring($tz, 1, 1) = '+') and                           substring($tz, 4, 1) = ':'">
               <xsl:value-of select="$tz" />
            </xsl:if>
         </xsl:otherwise>
      </xsl:choose>
   </xsl:variable>
   <xsl:variable name="year">
      <xsl:if test="not(string($timezone)) or                     $timezone = 'Z' or                      (substring($timezone, 2, 2) &lt;= 23 and                      substring($timezone, 5, 2) &lt;= 59)">
         <xsl:variable name="dt"
                       select="substring($dt-no-neg, 1, $dt-no-neg-length - string-length($timezone))" />
         <xsl:variable name="dt-length"
                       select="string-length($dt)" />
         <xsl:if test="number(substring($dt, 1, 4)) and                        ($dt-length = 4 or                         (substring($dt, 5, 1) = '-' and                          substring($dt, 6, 2) &lt;= 12 and                          ($dt-length = 7 or                           (substring($dt, 8, 1) = '-' and                            substring($dt, 9, 2) &lt;= 31 and                            ($dt-length = 10 or                             (substring($dt, 11, 1) = 'T' and                              substring($dt, 12, 2) &lt;= 23 and                              substring($dt, 14, 1) = ':' and                              substring($dt, 15, 2) &lt;= 59 and                              substring($dt, 17, 1) = ':' and                              substring($dt, 18) &lt;= 60))))))">
            <xsl:value-of select="substring($dt, 1, 4)" />
         </xsl:if>
      </xsl:if>
   </xsl:variable>
   <func:result select="($year mod 4 = 0 and                          $year mod 100 != 0) or                         $year mod 400 = 0" />
</func:function>

Change History

Submitted: 2001-05-13
Creator: Jeni Tennison(http://www.jenitennison.com/)

Returns true if the year given in a date/time string is a leap year.