EXSLT - set:trailing - XSLT Template Implementation

Supported Version: 1
XML Definition: set.trailing.xml
Source: set.trailing.template.xsl

Source

<xsl:template name="set:trailing">
   <xsl:param name="nodes"
              select="/.." />
   <xsl:param name="node"
              select="/.." />
   <xsl:variable name="end-node"
                 select="$node[1]" />
   <xsl:choose>
      <xsl:when test="not($end-node) or not($nodes)">
         <xsl:apply-templates select="$nodes"
                              mode="set:trailing" />
      </xsl:when>
      <xsl:when test="count($nodes | $end-node) != count($nodes)" />
      <xsl:when test="count($nodes[1] | $end-node) = 1">
         <xsl:apply-templates select="$nodes[position() > 1]"
                              mode="set:trailing" />
      </xsl:when>
      <xsl:otherwise>
         <xsl:call-template name="set:trailing">
            <xsl:with-param name="nodes"
                            select="$nodes[position() > 1]" />
            <xsl:with-param name="node"
                            select="$end-node" />
         </xsl:call-template>
      </xsl:otherwise>
   </xsl:choose>
</xsl:template>
<xsl:template match="node()|@*"
              mode="set:trailing">
   <xsl:copy-of select="." />
</xsl:template>

Change History

Submitted: 2001-03-28
Creator: Jeni Tennison(http://www.jenitennison.com)

Returns the nodes in one node set that come after a particular node.

Version	Modified	By	Details
1.1	2001-05-08	Jeni Tennison	Added a description of how the template-equivalent to the function works.
1.2	2001-05-22	Jeni Tennison	Added vendor implementations in Saxon and 4XSLT Changed status to stable
1.3	2001-06-11	Jeni Tennison	Added vendor implementation in jd.xslt.
1.4	2001-08-23	Jeni Tennison	Added vendor implementation in libxslt.
1.5	2002-08-20	Craig Stewart	Added Xalan-J implementation to the list.
1.6	2002-11-12	Craig Stewart	Updated 4XSLT version to 0.12.0a3.

Copyright

This material is in the public domain.